10 AT=679:FORI=AT TO AT+22:READX:POKEI,X:NEXT:PRINT"[147]":AS=3
20 DATA32,180,2,132,251,32,180,2
30 DATA166,251,76,240,255,32,253,174
40 GOTO610
50 LE=LEN(A$):E=(20+LE/2):FOR A=1 TO LE:
55 B$=MID$(A$,LE+1-A,1):PRINTB$;
60 FOR B=1 TO E:PRINT"[157] "B$;
65 NEXT:PRINT:PRINT"[145]";
70 E=E-1:NEXT
80 RETURN
100 DATA32,158,173,32,170,177,96
110 POKEVO,15:POKEWV,17:POKEAK,15:POKEHI,58:POKELO,149
120 FORTM=1TO100:NEXTTM:POKEWV,0
130 POKEWV,17:POKEHI,34:POKELO,75:FORTM=1TO100:NEXTTM:POKEWV,0:RETURN
140 REM - SETUP SCREEN
150 SYS AT,1,12:PRINT"SLIDING CHECKERS[146]";
160 ER=0:FR$="":CT=FRE(0)
170 SYS AT,9,8:PRINT"[159]1[146]  2[146]  3[146]  4[146]  5[146]  6[146]  7[146]  8[146]  9[146]";
180 SYS AT,11,7:PRINTA$(B(1))U$A$(B(2))U$A$(B(3))U$A$(B(4));
190 SYS AT,11,19:PRINTA$(B(5))U$A$(B(6))U$A$(B(7))U$A$(B(8))U$A$(B(9))
200 IF F2$="*" THEN GOSUB110
210 SYS AT,18,15:PRINT"[154]MOVE #";
220 IF AS=3 THEN 815
230 IF D$=E$ THEN ER=3:GOTO480
240 IF AS<>1 THEN270
250 ZZ=ZZ+1:FR$=MID$(SLV$,ZZ,1):SYS AT,15,24:PRINTFR$;
260 FOR TM=1TO750:NEXT:GOTO330
270 PRINT:PRINT"[145][145][145]     [154](F1 [154]- AUTO SOLVE ... F7 [154]- END)"
275 SYS AT,15,12:PRINT"[154]ENTER MOVE:  [157]";:POKE198,0
280 GET FR$
290 FOR I=1TO11:IFFR$=MID$("[133][136]123456789",I,1)THENPRINTFR$;:GOTO310
300 NEXT:GOTO280
310 IF FR$="[133]" THEN AS=1:SYS AT,3,14:PRINT"AUTO SOLVING":GOTO700
320 IF FR$="[136]" THEN ER=5:AS=2:GOTO480:REM - END
330 FR=VAL(FR$):IF C(FR)=3 THENER=1:GOTO480
340 FOR X=1TO9:IFMID$(D$,X,1)="3" THEN TU=X
350 NEXT
360 REM - CHECK FOR LEGAL MOVE
370 IF ABS(FR-TU)>2 THEN ER=2:GOTO480
380 IF ABS(FR-TU)=2 THEN IF FR<TU THEN IF C(FR)=C(FR+1) THEN ER=2:GOTO480
390 IF ABS(FR-TU)=2 THEN IF FR>TU THEN IF C(FR)=C(FR-1) THEN ER=2:GOTO480
400 IF C(FR)=1 THEN IF FR>TU THEN ER=2:GOTO480
410 IF C(FR)=2 THEN IF FR<TU THEN ER=2:GOTO480
420 REM - SWITCH PIECES
430 C=C(TU):C(TU)=C(FR):C(FR)=C
440 D$="":FORX=1TO9:D$=D$+RIGHT$(STR$(C(X)),1):NEXT
450 FORX=1TO9:B(X)=C(X):NEXT:F2$="*"
460 MV=MV+1:MV$="":MV$=STR$(MV):SYS AT,18,22:PRINT MV$;:GOTO150
470 REM - MSG RTN
480 IF AS=1 THEN ER=4
490 B1=490+(ER*10):POKE785,188:POKE786,168:POKEB1,PEEK(B1):B1=USR(0)
500 ER$="[150]'FROM[150]' POSITION EMPTY[146]":GOTO550
510 ER$="[150]INVALID ENTRY[146]":GOTO550
520 ER$="[154]CONGRATULATIONS!![146]":GOTO550
530 ER$="[154]PUZZLE SOLVED![146]":GOTO550
540 ER$="[154]THANKS FOR PLAYING![146]"
550 C=(22-LEN(ER$)/2):FORX=1TO5:SYS AT,24,C:PRINTER$;:FORTM=1TO100:NEXTTM
560 POKE781,24:SYS59903:FORTM=1TO100:NEXTTM,X
570 ER$="":F2$="":IF ER<3 THEN150
580 IF AS<>2 THEN590
581 RUN
590 ER=5:AS=2:GOTO490
600 REM - INITIALIZATION
610 DIM A$(3),B(9),C(9):POKE53280,.
620 U$="[145][145]"
630 A$(1)="   [157][157][157] [146][154][209] [157][157][157]   [146]"
640 A$(2)="   [157][157][157] [146][209] [157][157][157]   [146]"
650 A$(3)="   [157][157][157] [158]  [157][157][157]   [146]"
660 E$="222231111":REM - SOLUTION FORMAT
670 REM - SOUND PARAMETERS
680 VO=54296:WV=54276:AK=54277:HI=54273:LO=54272
690 REM - AUTOSOLVE MODE
700 D$="111132222":REM - PUZZLE FORMAT
710 FORX=1TO9:B(X)=VAL(MID$(D$,X,1)):C(X)=B(X):NEXT
720 IF AS=3 THEN 1000
730 MV=0:ZZ=0:F2$="":SYS AT,18,22:PRINT"   ";
740 REM - SOLUTION STRING
750 SLV$="467532468975312468753465"
760 PRINT"";:GOTO150
770 REM - INTRODUCTION
780 PRINTCHR$(142)"[147]":POKE53281,0:SYS AT,1,12:PRINT"SLIDING CHECKERS[146]":PRINT
790 PRINT"  FOUR BLUE AND FOUR WHITE CHECKERS"
800 PRINT" ARE ARRANGED AS FOLLOWS:"
810 AS=3:GOTO150
815 PRINT:PRINT"          [154]PRESS SPACE[146][154] TO CONTINUE":POKE198,.
816 IFPEEK(203)<>60THEN816
820 PRINT"[147]":SYS AT,1,12:PRINT"SLIDING CHECKERS[146]":PRINT
830 PRINT"  [154]REVERSE THE POSITIONS OF THE CHECKERS.":PRINT
840 PRINT"  BLUE CHECKERS MOVE ONLY TO THE":PRINT" RIGHT; WHITE CHECKERS TO ";
850 PRINT"THE LEFT.":PRINT
860 PRINT"  YOU MAY MOVE TO AN EMPTY SPACE OR"
870 PRINT" JUMP OVER AN OPPOSITE CHECKER.":PRINT
880 PRINT"  PRESS F1[154] FOR AUTO-SOLVE; F7[154]":PRINT" TO END.":PRINT
890 PRINT"  THIS PUZZLE CAN BE SOLVED IN 24":PRINT" MOVES."
900 SYS AT,22,8:PRINT"PRESS SPACE[146][154] TO CONTINUE":POKE198,.
910 GET RT$:IF RT$<>" " THEN910
920 AS=0:F2$="":PRINT"[147]":GOTO1000
1000 POKE53280,.:POKE53281,.:PRINTCHR$(142)"[147]"
1005 A$="S L I D I N G   C H E C K E R S":GOSUB50:PRINT
1010 PRINT"[158]":A$="BY DANIEL MILLER":GOSUB50
1015 PRINT"          I [154]- INSTRUCTIONS"
1020 PRINT"          P [154]- PLAY SLIDING CHECKERS"
1030 PRINT"          Q [154]- QUIT"
1040 PRINT"          PRESS P [154]OR Q[154]."
1050 A=PEEK(203):IFA<>33ANDA<>41ANDA<>62THEN1050
1060 IFA=41THENPRINT"[147]":AS=.:GOTO150
1070 IFA=33THEN780
60000 PRINT"[145]  [154]ARE YOU SURE YOU WANT TO QUIT? (Y[154]/N[154])"
60010 A=PEEK(203):IFA<>25ANDA<>39THEN60010
60020 IFA=39THENPRINT"[145]                                      [145]":GOTO1040
60030 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
60040 IFER<>63THENEND
60050 LOAD"HELLO CONNECT",8